* Definisanje funkcije "wc(nom, tol, index)"
* namenjena je da vraca ekstremalne vrdnosti parametara + nominalne
* za kolo sa dva parametra, vraca 4 kombinacije ekstremalnih 
* i jednu za nominalnu vrednost parametara (u 5 analiza)
* parametri funkcije: 
*  nom=nominalna vrednost parametra
*  tol= tolerancija parametra [x/100]
*  index=(broj_parametara_koji_se menja -1)
* funkcija vraca 
* vrednost nom*(1+tol) ako je binary(run, index)=1 i
* vrednost nom*(1-tol) ako je binary(run, index)=0
.func wc(nom,tol,index) 
+     {if(run==numruns,
+        nom,
+         if(binary(run,index),
+           nom*(1+tol),
+           nom*(1-tol)))}

*Definisanje funkcije "binary(run,index)"
*  Najpre treba znati da
* funkcija floor(x) vraca intedžer jednak ili manji od x
*    primer: floor(2.4)=2 a i floor(2)=2
*
*  run=redni broj analize zadat naredbom .step
*  index=(broj_parametara_koji_se menja -1)
*
* Funkcija binary vreca 0 ili 1
*     primer: za run=0, index=0 vraca 0=floor(0/1)-2*floor(0/2)
*                run=0, index=1 vraca 0=floor(0/2)-2*floor(0/4)
*                run=1, index=0 vraca 1=floor(1/1)-2*floor(1/2)
*                run=1, index=1 vraca 0=floor(1/2)-2*floor(1/4)
* 
.func binary(run,index) 
+   {floor(run/(2**index))-2*floor(run/(2**(index+1)))}